Email address considered not valid

This forum provides the support of Dezhi Mainframe systems. Please post your questions about logon, usage of our mainframe environment.

Moderators: sysprog, prino, sfan, steve-myers, Tim001

Email address considered not valid

Postby SDJRG » Tue 19 Aug 2014, 18:26

Hi

I tried to register for the board using an email address with a .biz domain but this was rejected, although it was OK for creating a ID on the Dezhi mainframe. Is it possible for this to be changed? The correct email address is on the mainframe.

I assume that if I use ROUTCDE=11,MCSFLAG=HRDCPY on WTO this not bother the operators?

STCK looks like it gives GMT/UST but JES has local time, is this just a configuration 'thing'? I've always worked in the UK so I've never seen a difference.

The Dezhi mainframe is brilliant, I just wish I had found it years ago :D

When I find my paypal password I will be making a donation.
Thanks
John
USER=SDJRG
SDJRG
 
Posts: 2
Joined: Thu 14 Aug 2014, 15:59

Re: Email address considered not valid

Postby steve-myers » Tue 19 Aug 2014, 18:42

As far as I know, there is no "real" operator console that is actively monitored; even if there is I certainly do not have access to it. I do not know if ROUTCDE=11,MCSFLAG=HRDCPY would display on it. It will display in SYSLOG.

The Fadezhi mainframe does not have access to the Email addresses used when userids are registered. I do not have access to the web code.
steve-myers
 
Posts: 452
Joined: Tue 04 May 2010, 15:43

Re: Email address considered not valid

Postby steve-myers » Tue 19 Aug 2014, 23:04

STCK looks like it gives GMT/UST but JES has local time, is this just a configuration 'thing'? I've always worked in the UK so I've never seen a difference.

Yes. In theory, the hardware time of day clock has a 0 time of January 1, 1900 GMT. The adjustment to local time is performed by applying two 64 bit constants in the CVT extension. First you subtract the contents of CVTLSO (the number of leap seconds) and add CVTLDTO (the time zone adjustment). Do not use CVTTZ. CVTTZ is a 32 bit value, not a 64 bit value, and it does not include the leap second adjustment. I'm not sure how CVTLDTO and CVTLSO are set. In our system, LSO is 0, and LDTO is -73728000000000.
Code: Select all
         USING CVTXTNT2,2
         USING CVTMAP,3 
         ...
         L     3,CVTPTR
         L     2,CVTEXT2
         STCK  CLOCK   
         LG    0,CLOCK 
         SLG   0,CVTLSO
         ALG   0,CVTLDTO
         STG   0,CLOCK 
In theory, in the UK you should see a difference, especially in the summer. Your "summer" time is definitely not GMT!

I'm not sure what you mean by "JES has local time." The JES2 checkpoint has a field derived from the Time of Day clock. As far as I know, all other times in JES2 are derived from the TIME macro. TIME BIN and TIME DEC both return local time; these are the times usually used by JES2.

The code snippet was tested on a system using a real external clock, as opposed to Fandezhi.
steve-myers
 
Posts: 452
Joined: Tue 04 May 2010, 15:43

Re: Email address considered not valid

Postby prino » Wed 20 Aug 2014, 07:52

SDJRG wrote:I tried to register for the board using an email address with a .biz domain but this was rejected, although it was OK for creating a ID on the Dezhi mainframe. Is it possible for this to be changed? The correct email address is on the mainframe.


I blocked .biz a long time a go, due to the extremely high volume of spammers using it to register. I you want (never tried this) I can probably change your registered address to a PM'ed .biz, but I'm reluctant to open it up ful0scae again.

As for Steve's remark about the email addresses on z/OS no being accessible, I think this is not true, but given that the system runs z/OS 1.6, getting into USS and navigating to wherever they are potentially held would be hard (on z/OS 1.10 it would be easy via ISPF 3.17), so I've never tried.

Robert
Robert AH Prins
robert.ah.prins @ the.17+Gb.Google thingy
Some programming here :mrgreen:
prino
 
Posts: 479
Joined: Sat 06 Jun 2009, 21:41
Location: Vilnius, Lithuania

Re: Email address considered not valid

Postby SDJRG » Wed 20 Aug 2014, 10:52

Hi Steve

RE local time, I meant as shown in JESMSGLG
05.27.46 JOB41250 ---- WEDNESDAY, 20 AUG 2014 ----

I've added your code to my routine and now get
2014-08-20-10:27:47.058593 GMT
2014-08-20-05:27:47.058593 LOC
Thanks for that.

I've used STCK STCKCONV for years (summer and winter) and always got a time that matched JESMSGLG. It makes me think my last site (15 years) was doing something non standard to the TOD.
I've emailed the sysprog to find out how it was set, but he's on holiday for two weeks.

Always something else to learn...

Cheers
John
SDJRG
 
Posts: 2
Joined: Thu 14 Aug 2014, 15:59

Re: Email address considered not valid

Postby steve-myers » Wed 20 Aug 2014, 14:49

I think your "real" site stores the local time in the TOD clock and change it when the local time changes.

The TOD clock fiction is it started at 00:00 January 1, 1900 and has run continuously since then, which is why there is a leap second adjustment.

I don't know how accurate the TOD clock on modern hardware is. The official specification for the 165/168 was 1 second in 24 hours, which is pretty sad, though that was 32 years ago.

In any event -
Code: Select all
SHOWTOD  CSECT
         USING *,12
         SAVE  (14,12),,*
         LR    12,15
         LA    15,SAVEAREA
         ST    13,4(,15)
         ST    15,8(,13)
         LR    13,15
         STCK  CLOCK
         BAS   14,STCKCONV
         BAS   14,LISTTIME
         USING CVTXTNT2,2
         USING CVTMAP,3
         L     3,CVTPTR
         L     2,CVTEXT2
         LG    0,CLOCK
         SLG   0,CVTLSO
         ALG   0,CVTLDTO
         STG   0,CLOCK
         BAS   14,STCKCONV
         BAS   14,LISTTIME
         TIME  DEC
         BAS   14,LISTTIME
         L     13,4(,13)
         RETURN (14,12),T,RC=0
         CNOP  0,8
LISTTIME BASR  15,0
         SAVE  (14,1),,LISTTIME
         ST    1,DWORK
         ST    0,DWORK+4
         MVC   DECTIME,EDMASK
         ED    DECTIME,DWORK
         LA    0,L'DECTIME-1
         LA    1,DECTIME+1
         TPUT  (1),(0),R
         RETURN (14,1),T
         CNOP  0,8
STCKCONV BASR  15,0
         SAVE  (14,1),,STCKCONV    SAVE REGISTERS
         STCKCONV STCKVAL=CLOCK,CONVVAL=RESULT,  CONVERT TOD CLOCK    ->
               TIMETYPE=DEC,DATETYPE=YYYYDDD
         MVC   20(4,13),RESULT     REPLACE CALLER'S REG 0 WITH        ->
                                    X'HHMMSSTH'
* CONVERT X'0YYYYDDD' FROM STCKCONV TO X'0CYYDDDF'
         L     1,RESULT+8          LOAD X'0YYYYDDD'
         SLL   1,4                 MAKE X'0YYYYDDD' X'YYYYDDD0'
         O     1,=A(X'0C')         ADD THE PACKED DECIMAL SIGN
         ST    1,24(,13)           REPLACE CALLER'S REG 1 W/ P'YYYYDDD'
         SP    24(4,13),=P'1900000' CONVERT P'YYYYDDD' TO P'CYYYDDD'
         OI    27(13),X'0F'        REPLACE THE SIGN
         RETURN (14,1),T           RESTORE REGISTERS & RETURN
SAVEAREA DC    9D'0'
DWORK    DC    D'0'
CLOCK    DC    XL8'0'
RESULT   DC    XL16'0'
         LTORG ,
DECTIME  DC     C' 0CYY/DDD HH:MM:SS.TH'
EDMASK   DC    0C' 0CYY/DDD HH:MM:SS.TH',C' ',X'21202020',C'/',X'202020>
               ',C' ',X'2020',C':',X'2020',C':',X'2020',C'.',X'2020'
         DC    0D'0'
         PUSH  PRINT
         PRINT NOGEN
         CVT   DSECT=YES
         POP   PRINT
         END   SHOWTOD
It was written and run on Fandezhi.
steve-myers
 
Posts: 452
Joined: Tue 04 May 2010, 15:43


Return to Dezhi systems: Mainframe

Who is online

Users browsing this forum: No registered users and 0 guests

cron